एसएएस में वेरिएबल्स का नाम कैसे बदलें (उदाहरण के साथ)

आप एसएएस डेटासेट में एक या अधिक वेरिएबल्स का नाम बदलने के लिए नाम बदलें फ़ंक्शन का उपयोग कर सकते हैं।

यह फ़ंक्शन निम्नलिखित मूल सिंटैक्स का उपयोग करता है:

 data new_data;
    set original_data ( rename =(old_name=new_name));
run ;

निम्नलिखित उदाहरण दिखाते हैं कि निम्नलिखित डेटासेट के साथ व्यवहार में इस फ़ंक्शन का उपयोग कैसे करें:

 /*create dataset*/
data original_data;
    input xyz;
    datalines ;
1 4 76
2 3 49
2 3 85
4 5 88
2 2 90
;
run ;

/*view dataset*/
proc print data = original_data; 

उदाहरण 1: एक वेरिएबल का नाम बदलें

निम्नलिखित कोड दिखाता है कि डेटासेट में केवल x वेरिएबल का नाम कैसे बदला जाए:

 /*rename one variable*/
data new_data;
set original_data ( rename =(x=new_x));
run ;

/*view new dataset*/
proc print data = new_data;

ध्यान दें कि x का नाम बदलकर new_x कर दिया गया, लेकिन अन्य सभी वेरिएबल नाम वही रहे।

उदाहरण 2: अनेक चरों का नाम बदलें

निम्नलिखित कोड दिखाता है कि डेटासेट में x और y वेरिएबल्स का नाम कैसे बदला जाए।

ध्यान दें कि आपको नए वेरिएबल नामों के बीच अल्पविराम शामिल करने की आवश्यकता नहीं है।

 /*rename multiple variables*/
data new_data;
    set original_data ( rename =(x=new_x y=new_y));
run ;

/*view new dataset*/
proc print data=new_data; 

उदाहरण 3: सभी चरों में एक उपसर्ग जोड़ें

निम्नलिखित कोड दिखाता है कि डेटासेट में सभी वेरिएबल्स में _NEW उपसर्ग कैसे जोड़ा जाए:

 /*define prefix to append to each variable*/
proc sql noprint ;
   select cats(name, '=', '_NEW', name)
          into :list
          separated by ' '
          from dictionary.columns
          where libname = 'WORK' and memname = 'ORIGINAL_DATA';
quit ;

/*add prefix to each variable in dataset*/
proc datasets library = work;
   modify original_data;
   rename &list;
quit ;

/*view updated dataset*/
proc print data = original_data; 

उदाहरण 4: सभी चरों में एक प्रत्यय जोड़ें

निम्नलिखित कोड दिखाता है कि डेटासेट में सभी वेरिएबल्स में _NEW प्रत्यय कैसे जोड़ा जाए:

 /*define suffix to append to each variable*/
proc sql noprint ;
   select cats(name, '=', name, '_NEW')
          into :list
          separated by ' '
          from dictionary.columns
          where libname = 'WORK' and memname = 'ORIGINAL_DATA';
quit ;

/*add suffix to each variable in dataset*/
proc datasets library = work;
   modify original_data;
   rename &list;
quit ;

/*view updated dataset*/
proc print data = original_data; 

अतिरिक्त संसाधन

निम्नलिखित ट्यूटोरियल बताते हैं कि एसएएस में अन्य सामान्य कार्य कैसे करें:

एसएएस में लुप्त मानों को शून्य से कैसे बदलें
एसएएस में डुप्लिकेट कैसे हटाएं
एसएएस में डेटा को सामान्य कैसे करें