Sas에서 변수 이름을 바꾸는 방법(예제 포함)

이름 바꾸기 함수를 사용하여 SAS 데이터세트에서 하나 이상의 변수 이름을 바꿀 수 있습니다.

이 함수는 다음 기본 구문을 사용합니다.

 data new_data;
    set original_data ( rename =(old_name=new_name));
run ;

다음 예에서는 다음 데이터세트에서 실제로 이 함수를 사용하는 방법을 보여줍니다.

 /*create dataset*/
data original_data;
    input xyz;
    datalines ;
1 4 76
2 3 49
2 3 85
4 5 88
2 2 90
;
run ;

/*view dataset*/
proc print data = original_data; 

예시 1: 변수 이름 바꾸기

다음 코드는 데이터 세트에서 x 변수의 이름만 바꾸는 방법을 보여줍니다.

 /*rename one variable*/
data new_data;
set original_data ( rename =(x=new_x));
run ;

/*view new dataset*/
proc print data = new_data;

x 의 이름은 new_x로 바뀌었지만 다른 모든 변수 이름은 동일하게 유지되었습니다.

예시 2: 여러 변수의 이름 바꾸기

다음 코드는 데이터 세트에서 x 및 y 변수의 이름을 바꾸는 방법을 보여줍니다.

새 변수 이름 사이에 쉼표를 포함할 필요는 없습니다.

 /*rename multiple variables*/
data new_data;
    set original_data ( rename =(x=new_x y=new_y));
run ;

/*view new dataset*/
proc print data=new_data; 

예시 3: 모든 변수에 접두사 추가

다음 코드는 데이터 세트의 모든 변수에 _NEW 접두사를 추가하는 방법을 보여줍니다.

 /*define prefix to append to each variable*/
proc sql noprint ;
   select cats(name, '=', '_NEW', name)
          into :list
          separated by ' '
          from dictionary.columns
          where libname = 'WORK' and memname = 'ORIGINAL_DATA';
quit ;

/*add prefix to each variable in dataset*/
proc datasets library = work;
   modify original_data;
   rename &list;
quit ;

/*view updated dataset*/
proc print data = original_data; 

예시 4: 모든 변수에 접미사 추가

다음 코드는 데이터 세트의 모든 변수에 _NEW 접미사를 추가하는 방법을 보여줍니다.

 /*define suffix to append to each variable*/
proc sql noprint ;
   select cats(name, '=', name, '_NEW')
          into :list
          separated by ' '
          from dictionary.columns
          where libname = 'WORK' and memname = 'ORIGINAL_DATA';
quit ;

/*add suffix to each variable in dataset*/
proc datasets library = work;
   modify original_data;
   rename &list;
quit ;

/*view updated dataset*/
proc print data = original_data; 

추가 리소스

다음 튜토리얼에서는 SAS에서 다른 일반적인 작업을 수행하는 방법을 설명합니다.

SAS에서 누락된 값을 0으로 바꾸는 방법
SAS에서 중복을 제거하는 방법
SAS에서 데이터를 정규화하는 방법