SAS : Comment tracer des moyennes avec des barres d’erreur standard

Vous pouvez utiliser la syntaxe suivante dans SAS pour créer un tracé de valeurs moyennes avec des barres d’erreur standard par groupe :

/*calculate mean and standard error of points for each team*/
proc sql;
create table groupPlot as
select 
    team, 
    mean(points) as meanPoints, 
    mean(points) - stderr(points) as lowStdPoints,    
    mean(points) + stderr(points) as highStdPoints
from my_data
group by team;
quit;

/*create plot with mean and standard error bars of points for each team*/
proc sgplot data=groupPlot;
scatter x=team y=meanPoints / 
    yerrorlower=lowStdPoints yerrorupper=highStdPoints group=team;
series x=team y=meanPoints / group=team;
run;

Cet exemple particulier utilise PROC SQL pour calculer la valeur moyenne de la variable de points , regroupée par la variable d’équipe dans un ensemble de données.

Nous utilisons ensuite PROC SGPLOT pour créer un tracé qui montre la valeur moyenne de la variable de points ainsi que les barres d’erreur standard, regroupées par variable d’équipe .

L’exemple suivant montre comment utiliser cette syntaxe dans la pratique.

Exemple : traçage des moyennes avec des barres d’erreur standard dans SAS

Supposons que nous disposions de l’ensemble de données suivant contenant des informations sur les points marqués par les basketteurs de différentes équipes :

/*create dataset*/
data my_data;
    input team $ points;
    datalines;
A 29
A 23
A 20
A 21
A 33
B 14
B 13
B 17
B 14
B 15
C 21
C 22
C 20
C 25
C 24
;
run;

/*view dataset*/
proc print data=my_data;

Supposons que nous souhaitions créer un graphique montrant la valeur moyenne des points ainsi que des barres d’erreur standard pour chaque équipe .

Nous pouvons utiliser la syntaxe suivante pour ce faire :

/*calculate mean and standard error of points for each team*/
proc sql;
create table groupPlot as
select 
    team, 
    mean(points) as meanPoints, 
    mean(points) - stderr(points) as lowStdPoints,    
    mean(points) + stderr(points) as highStdPoints
from my_data
group by team;
quit;

/*create plot with mean and standard error bars of points for each team*/
proc sgplot data=groupPlot;
scatter x=team y=meanPoints / 
    yerrorlower=lowStdPoints yerrorupper=highStdPoints group=team;
series x=team y=meanPoints / group=team;
run;

Les petits cercles montrent la valeur moyenne des points pour chaque équipe et les barres s’étendant des cercles montrent l’erreur type des points pour chaque équipe .

Nous pouvons également imprimer le tableau que nous avons créé à l’aide de PROC SQL pour voir les valeurs réelles de la moyenne et de l’erreur standard :

/*print mean and standard error of points for each team*/
proc print data=groupPlot;

Les valeurs de ce tableau correspondent à celles indiquées dans le graphique ci-dessus.

Ressources additionnelles

Les didacticiels suivants expliquent comment créer d’autres graphiques dans SAS :

Comment créer des tracés linéaires dans SAS
Comment créer des boxplots par groupe dans SAS
Comment créer un nuage de points avec une ligne de régression dans SAS